Excel MIN Function: Find the Lowest Value and Its Name

The Excel MIN function returns the smallest number in a set of values. Use it to find the lowest sale, score, price or the earliest date.

fx=MIN(number1, [number2], ...)

`number1`	The first number, cell or range, such as `C3:C8`.
`number2, ...` optional	More numbers, cells or ranges, up to 255 in total.

Table of Contents

Basic example

To find the lowest January sale, give MIN the January column:

=MIN(C3:C8)

The smallest value in C3:C8 is 280, for Eraser.

Give MIN a block of cells to search all three months at once:

=MIN(C3:E8)

The lowest sale across January to March is 260, Eraser in March.

Combine MIN with INDEX and MATCH to return the name of the product with the lowest sale:

=INDEX(B3:B8,MATCH(MIN(C3:C8),C3:C8,0))

MIN finds 280, MATCH finds its position (5), and INDEX returns Eraser. In Excel 365 you can use =XLOOKUP(MIN(C3:C8),C3:C8,B3:B8) instead.

Formula	Result	What it does
`=SMALL(C3:C8,2)`	450	Second-lowest January sale
`=MINIFS(E3:E8,C3:C8,">500")`	580	Lowest March sale where January was over 500
`=MIN(C3*10%,40)`	40	Caps a 10% bonus at 40
`=MIN(C3:C8,500)`	280	Lowest of a range and a fixed number

MIN ignores text, empty cells and TRUE/FALSE inside ranges.
If there are no numbers, MIN returns 0. Watch for this with dates: an empty range shows as 00-Jan-1900.
Dates are numbers, so =MIN(dates) returns the earliest date.
MIN is often used to set a maximum: =MIN(value,cap) never returns more than the cap.

Problem	Cause	Fix
Result is 0	No real numbers in the range, or a zero you didn’t expect	Check for numbers stored as text; use `MINIFS(range,range,"<>0")` to skip zeros
`#N/A`, `#VALUE!`	An error cell inside the range	Fix the source, or use `AGGREGATE(5,6,range)`
Earliest date shows 00-Jan-1900	The date range is empty	Wrap it: `=IF(COUNT(range),MIN(range),"")`

Practice file

All three examples plus the related formulas in a cheat sheet.